Gecko [ casapremiada.novaexata.com.br ]

Name	Size	Permission
tapset	[ DIR ]	drwxr-xr-x
alias_suffixes.meta	724 B	-rw-r--r--
alias_suffixes.stp	1.04 KB	-rwxr-xr-x
also_ran.meta	605 B	-rw-r--r--
also_ran.stp	769 B	-rwxr-xr-x
ansi_colors.meta	406 B	-rw-r--r--
ansi_colors.stp	716 B	-rwxr-xr-x
ansi_colors2.meta	467 B	-rw-r--r--
ansi_colors2.stp	738 B	-rwxr-xr-x
badname.meta	459 B	-rw-r--r--
badname.stp	1.3 KB	-rwxr-xr-x
badname.txt	126 B	-rw-r--r--
callgraph.meta	388 B	-rw-r--r--
callgraph.stp	212 B	-rwxr-xr-x
callgraph.txt	3.61 KB	-rw-r--r--
click.wav	1.26 KB	-rw-r--r--
cpu_throttle.meta	795 B	-rw-r--r--
cpu_throttle.stp	1.45 KB	-rwxr-xr-x
eventcount.meta	637 B	-rw-r--r--
eventcount.stp	6.77 KB	-rwxr-xr-x
eventcount.txt	1.85 KB	-rw-r--r--
func_time_stats.meta	696 B	-rw-r--r--
func_time_stats.stp	520 B	-rwxr-xr-x
func_time_stats.txt	493 B	-rw-r--r--
grapher.stp	1.26 KB	-rwxr-xr-x
graphs.meta	453 B	-rw-r--r--
graphs.stp	1.46 KB	-rwxr-xr-x
helloworld.meta	298 B	-rw-r--r--
helloworld.stp	57 B	-rwxr-xr-x
key.meta	319 B	-rw-r--r--
key.stp	414 B	-rwxr-xr-x
keyhack.meta	355 B	-rw-r--r--
keyhack.stp	288 B	-rwxr-xr-x
measureinterval.meta	1.54 KB	-rw-r--r--
measureinterval.stp	830 B	-rwxr-xr-x
para-callgraph-verbose.meta	879 B	-rw-r--r--
para-callgraph-verbose.stp	407 B	-rwxr-xr-x
para-callgraph.meta	756 B	-rw-r--r--
para-callgraph.stp	405 B	-rwxr-xr-x
para-callgraph.txt	4.31 KB	-rw-r--r--
py2example.meta	489 B	-rw-r--r--
py2example.stp	761 B	-rw-r--r--
py2example.tcl	79 B	-rw-r--r--
py3example.meta	515 B	-rw-r--r--
py3example.stp	761 B	-rw-r--r--
py3example.tcl	79 B	-rw-r--r--
pyexample.py	832 B	-rw-r--r--
pyexample.pyc	1.06 KB	-rw-r--r--
pyexample.pyo	1.06 KB	-rw-r--r--
regex.meta	504 B	-rw-r--r--
regex.stp	491 B	-rwxr-xr-x
return.wav	6.43 KB	-rw-r--r--
sizeof.meta	499 B	-rw-r--r--
sizeof.stp	496 B	-rwxr-xr-x
sizeof.txt	100 B	-rw-r--r--
sizeof_interactive.meta	816 B	-rw-r--r--
sizeof_interactive.stp	572 B	-rw-r--r--
sizeof_interactive.txt	154 B	-rw-r--r--
socket-events.meta	563 B	-rw-r--r--
socket-events.stp	5.28 KB	-rwxr-xr-x
stopwatches.meta	754 B	-rw-r--r--
stopwatches.stp	957 B	-rwxr-xr-x
tcl-funtop.meta	479 B	-rw-r--r--
tcl-funtop.stp	817 B	-rwxr-xr-x
tcl-trace.meta	364 B	-rw-r--r--
tcl-trace.stp	1.01 KB	-rwxr-xr-x
varwatch.meta	583 B	-rw-r--r--
varwatch.stp	635 B	-rwxr-xr-x
varwatch.txt	2.62 KB	-rw-r--r--
watchdog.meta	922 B	-rw-r--r--
watchdog.stp	447 B	-rwxr-xr-x
whythefail.meta	481 B	-rw-r--r--
whythefail.stp	2.22 KB	-rw-r--r--
whythefail.txt	3.7 KB	-rw-r--r--

Code Editor : eventcount.stp

#!/usr/bin/stap

# General event counter / monitor.  Gives a report of event counts/rates on a
# per-process or systemwide basis at script shutdown.
# 
# Invoke with a list of probe point patterns as script command-line arguments:
# stap eventcount.stp 'syscall.*' ...
#
# Optionally, specify process/thread-id to limit analysis:
# stap eventcount.stp -c "CMD ARGS" [...probe points...]
# or stap eventcount.stp -x PID [...probe points...]
# or stap eventcount.stp -G comm=EXECNAME [...probe points...]
#
# Optionally, override periodic screen update, every NNN seconds (default 10)
# stap eventcount.stp -G period=NNN [...probe points...]
# ... or cumulative totals
# stap eventcount.stp -G period=0 [...probe points...]
#
# Optionally, specify cumulative mode for periodic updates
# stap eventcount.stp -G period=NNN -G cumulative=1 [...probe points...]
# stap eventcount.stp -G period=NNN -G cumulative=1 [...probe points...]
#
# Optionally, specify sorting other than by =count
# stap eventcount.stp -G sort=tid [...probe points...]
# stap eventcount.stp -G sort=count [...probe points...]
# stap eventcount.stp -G sort=event [...probe points...]
# stap eventcount.stp -G sort=unsorted [...probe points...]
#
# Optionally, specify a limit for sorted event count reports
# stap eventcount.stp -G lines=100 [...probe points...]
#
# Runtime controls:
#   'j': cycles forwards through the sort options
#   'k': cycles backwards through the sort options
#   'l': toggles cumulative mode
#
#   Pressing enter pauses the reporting and allows a new value for 'comm'
#   to be inputted. Doing so resets all counts. To return to analyzing
#   all processes leave 'comm' blank.

global period=10
global cumulative=0
global comm=""
global sort="count"
global sort_options
global lines=20

probe %($# == 0 || $# > 32 %? begin %: never %)
{
  printf("Please specify between 1 and 32 events to count.\n")
  exit()
}

global c%
global totalc, filteredc

//paramaterize up to 32 arguments
probe %($# >= 1 %? $1 %: never %),
      %($# >= 2 %? $2 %: never %),
      %($# >= 3 %? $3 %: never %),
      %($# >= 4 %? $4 %: never %),
      %($# >= 5 %? $5 %: never %),
      %($# >= 6 %? $6 %: never %),
      %($# >= 7 %? $7 %: never %),
      %($# >= 8 %? $8 %: never %),
      %($# >= 9 %? $9 %: never %),
      %($# >= 10 %? $10 %: never %),
      %($# >= 11 %? $11 %: never %),
      %($# >= 12 %? $12 %: never %),
      %($# >= 13 %? $13 %: never %),
      %($# >= 14 %? $14 %: never %),
      %($# >= 15 %? $15 %: never %),
      %($# >= 16 %? $16 %: never %),
      %($# >= 17 %? $17 %: never %),
      %($# >= 18 %? $18 %: never %),
      %($# >= 19 %? $19 %: never %),
      %($# >= 20 %? $20 %: never %),
      %($# >= 21 %? $21 %: never %),
      %($# >= 22 %? $22 %: never %),
      %($# >= 23 %? $23 %: never %),
      %($# >= 24 %? $24 %: never %),
      %($# >= 25 %? $25 %: never %),
      %($# >= 26 %? $26 %: never %),
      %($# >= 27 %? $27 %: never %),
      %($# >= 28 %? $28 %: never %),
      %($# >= 29 %? $29 %: never %),
      %($# >= 30 %? $30 %: never %),
      %($# >= 31 %? $32 %: never %),
      %($# >= 32 %? $32 %: never %)
{
  totalc <<< 1
  if (target() && ! target_set_pid(pid()))
    next
  if (comm != "" && execname() != comm)
    next
  filteredc <<< 1
  c[sprintf("%s(%d)",execname(),tid()), pn()]<<<1
}

probe begin {
      start_ms = gettimeofday_ms() 
      if (target()) msg = sprintf ("pid %d + children", target())
      else if (comm != "") msg = sprintf ("execname %s", comm)
      else msg = "unfiltered";
      printf("Starting event counting at %s, %s\n",
             tz_ctime(gettimeofday_s()), msg)
      format = sprintf("max %d lines, sorted by %s", lines, sort);
      if (period)
        printf("%s reporting (%s) every %d s\n",
               cumulative ? "Cumulative" : "Incremental",
               format, period)
      else
        printf("One-time cumulative reporting (%s) at script termination (^C)\n",
               format)

sort_options[0] = "count"
      sort_options[1] = "tid"
      sort_options[2] = "event"
      sort_options[3] = "unsorted"
}
global start_ms

function reportline(tid, name, countstr) {
  // fine-grained control over the column layout here
  printf("%-22s %-15s %s\n", tid, countstr, name)
}

function reportline2(tid, name, count, elapsed_ms) {
  reportline(tid, name,
             sprintf("%d (%d.%02d)", count,
                     (count * 100000 / elapsed_ms)/100,
                     (count * 100000 / elapsed_ms)%100))
}

global input_mode = "char"

function report () {
  elapsed_ms = gettimeofday_ms() - start_ms
  if (elapsed_ms < 0) elapsed_ms=1
  printf("%s time elapsed: %d ms, %d events, %d after filtering.\n",
         (cumulative ? "Cumulative" : "Period"),
         elapsed_ms, @count(totalc), @count(filteredc))

reportline("TID", "EVENT", "COUNT (Hz)")
  reportline("---", "-----", "----------")
  if (sort == "count")
    foreach([tid, name] in c- limit lines)
      reportline2(tid, name, @count(c[tid,name]), elapsed_ms)
  else if (sort == "tid")
    foreach([tid+, name] in c limit lines)
      reportline2(tid, name, @count(c[tid,name]), elapsed_ms)
  else if (sort == "event")
    foreach([tid, name+] in c limit lines)
      reportline2(tid, name, @count(c[tid,name]), elapsed_ms)
  else # unsorted
    foreach([tid, name] in c limit lines)
      reportline2(tid, name, @count(c[tid,name]), elapsed_ms)
}

probe end {
  report()
  printf("Finished event counting at %s.\n", tz_ctime(gettimeofday_s()))
}

probe timer.s(1) {
      if (period <= 0) next
      if ((gettimeofday_s() % period) == 0) {
         if (input_mode == "char")
		 report()
         if (! cumulative) {
             delete c
             delete filteredc
             delete totalc
             start_ms = gettimeofday_ms()
         }
      }
}

probe input.line {
    if (input_mode != "line")
            next
    // remove newline character
    comm = substr(line, 0, strlen(line) - 1)
    if (comm == "") {
        print("\nNow analyzing all processes")
    } else {
        print("\nNow analyzing process \"" . comm . "\"")
    }
    delete c
    delete filteredc
    delete totalc
}

global idx = 0 // index into sort_options

probe input.char {
     if (input_mode == "line") {
	     print(char)
	     if (char == "\n")
	         input_mode = "char"
     }
     else if (char == "j") {
	     idx = (idx + 1) % 4
	     sort = sort_options[idx]
	     println("Sorting by " . sort)
     }
     else if (char == "k") {
	     idx = idx ? (idx - 1) % 4 : 3
             sort = sort_options[idx]
	     println("Sorting by " . sort)
     }
     else if (char == "l") {
	     cumulative = 1 - cumulative
	     if (cumulative)
		     println("Cumulative mode enabled")
             else
		     println("Cumulative mode disabled")
     }
     else if (char == "\n") {
	     input_mode = "line"
	     println("Please enter a process name:")
     }
}

${this.title}

Code Editor : eventcount.stp